Received-SPF: pass (google.com: domain of abnf-discuss-bounces@ietf.org designates 2001:1900:3001:11::2c as permitted sender) client-ip=2001:1900:3001:11::2c;
Message-ID: <53E3B22E.5000708@alum.mit.edu>
Date: Thu, 07 Aug 2014 13:06:54 -0400
From: Paul Kyzivat <pkyzivat@alum.mit.edu>
User-Agent: Mozilla/5.0 (Macintosh; Intel Mac OS X 10.7;
 rv:24.0) Gecko/20100101 Thunderbird/24.6.0
MIME-Version: 1.0
To: "abnf-discuss@ietf.org" <abnf-discuss@ietf.org>
Archived-At: http://mailarchive.ietf.org/arch/msg/abnf-discuss/xMJQVz526a1rOGwrWqsktsuNvtY
Subject: [abnf-discuss] Case-sensitive string constants in ABNF
Precedence: list
Content-Transfer-Encoding: 7bit
Content-Type: text/plain; charset="us-ascii"; Format="flowed"
Errors-To: abnf-discuss-bounces@ietf.org
Sender: "abnf-discuss" <abnf-discuss-bounces@ietf.org>

Here is a concrete proposal for changes to RFC5234 that would add in 
case-sensitive strings using a prefix:

1) Revise the last half of section 2.3 (beginning with "ABNF permits the 
specification of literal text strings ") as follows:

    ABNF permits the specification of literal text strings directly,
    enclosed in quotation marks.  Hence:

          command     =  "command string"

    Literal text strings are interpreted as a concatenated set of
    printable characters. The character set for these strings is
    US-ASCII.

    Literal text strings in ABNF may be either case sensitive or case
    insensitive. The form of matching used with a literal text string is
    denoted by a prefix to the quoted string. The following prefixes are
    allowed:

         %s          =  case-sensitive
         %i          =  case-insensitive

    If no prefix is present then the string is case-insensitive.

    Hence:

          rulename = %i"abc"

    and:

          rulename = "aBc"

    will both match "abc", "Abc", "aBc", "abC", "ABc", "aBC", "AbC", and
    "ABC".

    In contrast:

          rulename = %s"aBc"

    will match only "aBc", and will not match "abc", "Abc", "abC",
    "ABc", "aBC", "AbC", or "ABC".
.
    Another way to define a rule that is case sensitive is to specify
    the individual characters numerically.

    For example:

          rulename    =  %d97 %d98 %d99

    or

          rulename    =  %x61.62.63

    will match only the string that comprises only the lowercase
    characters, abc.

2) Replace the char-val rule in section 4 with the following:

          char-val       =  case-insensitive-string /
                            case-sensitive-string

          case-insensitive-string =
                            [ "%i" ] quoted-string

          case-sensitive-string =
                            "%s" quoted-string

          quoted-string  =  DQUOTE *(%x20-21 / %x23-7E) DQUOTE
                                 ; quoted string of SP and VCHAR
                                 ;  without DQUOTE


Is there an xml2rfc version of RFC5234?

	Thanks,
	Paul

_______________________________________________
abnf-discuss mailing list
abnf-discuss@ietf.org
https://www.ietf.org/mailman/listinfo/abnf-discuss